<!--#include file="ini.inc"-->
<!--#include file="Piscitrol.inc" -->
<!--#include file="Password.inc" -->
<!--#include file="adovbs.inc"-->

<HTML>

<HEAD>
	<TITLE>Piscitrol: Ambiente</TITLE>
	<LINK REL="stylesheet" TYPE="text/css" HREF="Estilos.css">
	<% =sReload %>
</HEAD>

<BODY>

<%
	ID_Amb = Request.QueryString("ID_Amb")
	ID_Reg = Request.QueryString("ID_Reg")

	if Request.QueryString("ID_Reg") = "" then
		set rsMaxReg = server.CreateObject("ADODB.Recordset")
		sSQL = "SELECT Max(t_Registros.Reg_FechaFin) AS MaxOfReg_FechaFin " & _
			   "FROM t_Registros " & _
			   "WHERE t_Registros.Reg_Ambiente=" & ID_Amb & ";"
		'Response.Write sSQL
		rsMaxReg.open sSQL, cn, adOpenForwardOnly, adLockReadOnly, adCmdText
		if not rsMaxReg.EOF then
			if isdate(rsMaxReg("MaxOfReg_FechaFin")) then
				'Fecha = DateAdd("s",-2,rsMaxReg("MaxOfReg_FechaFin"))
				set rsRegistro = server.CreateObject("ADODB.Recordset")
				sSQL = "SELECT Reg_ID " & _
					   "FROM t_Registros " & _
					   "WHERE Reg_FechaFin=#" & Fecha2String(rsMaxReg("MaxOfReg_FechaFin")) & "# " & _
							 "AND Reg_Ambiente=" & ID_Amb & ";"
				'Response.Write sSQL
				rsRegistro.open sSQL, cn, adOpenForwardOnly, adLockReadOnly, adCmdText
				if not rsRegistro.EOF then
					ID_Reg = rsRegistro("Reg_ID")
					'Response.Write "ID_Reg" & ID_Reg
				end if
			end if
		end if
	end if
	
	set rsAmbiente = server.CreateObject("ADODB.Recordset")
	sqlAmbiente = "SELECT Mod_ID, Mod_Nombre, Amb_Nombre " & _
				  "FROM t_Modulos LEFT JOIN t_Ambientes ON t_Modulos.Mod_ID = t_Ambientes.Amb_Modulo " & _
				  "WHERE Amb_ID= " & ID_Amb & ";"
	'Response.Write sqlAmbiente
	rsAmbiente.open sqlAmbiente, cn, adOpenForwardOnly, adLockReadOnly, adCmdText

	set rsSensores = server.CreateObject("ADODB.Recordset")
	sqlSensores = "SELECT t_Sensores.Sen_ID, t_TipoVariables.TVa_Variable, t_Sensores.Sen_Ubicacion, t_Sensores.Sen_Valor, t_TipoVariables.TVa_Unidades, t_Sensores.Sen_AlarmaAlta, t_Sensores.Sen_AlarmaBaja, t_Sensores.Sen_AlarmaHOn, t_Sensores.Sen_AlarmaLOn, t_Controladores.Ctr_Conectado " & _
				  "FROM t_Controladores INNER JOIN (t_Entradas INNER JOIN (t_TipoVariables INNER JOIN (t_CatSensores INNER JOIN t_Sensores ON t_CatSensores.CSe_ID = t_Sensores.Sen_Tipo) ON t_TipoVariables.TVa_ID = t_CatSensores.CSe_Variable) ON t_Entradas.Ent_ID = t_Sensores.Sen_Entrada) ON t_Controladores.Ctr_ID = t_Entradas.Ent_Controlador " & _
				  "WHERE Sen_Ambiente= " & ID_Amb & " " & _
				  "ORDER BY t_TipoVariables.TVa_Variable, t_Sensores.Sen_Ubicacion;"
	'Response.Write sqlSensores
	rsSensores.open sqlSensores, cn, adOpenForwardOnly, adLockReadOnly, adCmdText

	%>
	<table border=0>
		<tr class=top>
			<td width=120px>LISTA</td>
				<td width=520px>
					<a href="Alarmas.asp" title="Ver listado de Alarmas en curso">Alarmas</a>
				</td>
			<td width=120px>MAPA</td>
		</tr>

		<tr class=top>
			<td><a href="ListadoModulos.asp" title="Ver listado de los Modulos">Modulos</a></td>
			<td><% =rsAmbiente("Mod_Nombre") %></TD>
			<td><a href="MapaGeneral.asp" title="Ver mapa de los Modulos">Modulos</a></td>
		</tr>

		<tr class=top>
			<td><a href="ListadoAmbientes.asp?ID_Mod=<% =rsAmbiente("Mod_ID") %>" title="Ver listado de los Ambientes">Ambientes</a></td>
			<td class=title><% =rsAmbiente("Amb_Nombre") %></TD>
			<td><a href="MapaModulo.asp?ID_Mod=<% =rsAmbiente("Mod_ID") %>" title="Ver listado de los Ambientes">Ambientes</a></td>
		</tr>

		<%
		if ID_Reg <> "" then
			set rsRegistro = server.CreateObject("ADODB.Recordset")
			sql = "SELECT Reg_Nombre, Reg_Ambiente, Reg_FechaIni, Reg_FechaFin " & _
				  "FROM t_Registros " & _
				  "WHERE Reg_ID=" & ID_Reg & ";"
			'Response.Write sql
			rsRegistro.open sql, cn, adOpenForwardOnly, adLockReadOnly, adCmdText
			%>
			<tr class=top>
				<td><a href="RegistrosAmbiente.asp?ID_Amb=<% =ID_Amb %>" title="Ver listado de los Registros">Registros</a></td>
				<td><a href="Registro.asp?ID_Reg=<% =ID_Reg %>" title="Ver detalle del Registro"><% =rsRegistro("Reg_Nombre") %></a></TD>
				<td><a href="RegistrosAmbiente.asp?ID_Amb=<% =ID_Amb %>" title="Ver listado de los Registros">Registros</a></td>
			</tr>
			<%
		end if
		%>

		<tr>
			<td class="opcion" valign="top"><!-- OPCIONES -->
				<table width="100%">
					<tr class="menu"><td align=center>Opciones</td></tr>
					<tr><td><a href="ListadoControles.asp?ID_Amb=<% =ID_Amb %>" title="Ver Controles">Controles</a></td></tr>
					<tr><td><a href="Salida.asp" title="Reiniciar como un nuevo usuario">Salir</a></td></tr>
				</table>
			</td>
			
			<td align="left" valign="top" colspan="2" style="position: relative;">
				<table width=100%>
					<tr class=head>
						<td width=40%>SENSOR</td>
						<td width=15%>MEDICION</td>
						<td width=15%>UNIDADES</td>
						<td width=15%>BAJA</td>
						<td width=15%>ALTA</td>
					</tr>

					<%
					While Not rsSensores.Eof
						iEnLinea = rsParametros("Prm_Encendido") and rsSensores("Ctr_Conectado")
						iAlarma = iEnLinea and (rsSensores("Sen_AlarmaLOn") or rsSensores("Sen_AlarmaHOn"))
						if iAlarma then
							strClass = "alarma"
						else
							strClass = "data"
						end if 

						sSensor = rsSensores("TVa_Variable")
						if  rsSensores("Sen_Ubicacion") <> "" then
							sSensor = sSensor & " " &  rsSensores("Sen_Ubicacion")
						end if

						if iEnLinea and not IsNull(rsSensores("Sen_Valor")) then
							Temp = FormatNumber(rsSensores("Sen_Valor"),1)
						else
							Temp = ""
						end if 
						%>

						<tr class=<% =strClass %>>
							<td>
								<a href="GraficoSensor.asp?ID_Sen=<% =rsSensores("Sen_ID") %>&ID_Reg=<% =ID_Reg %>" 
								   title="Ver gráfico del sensor <% =sSensor %>">
								   <% =sSensor %>
								</a>
							</td>
							<td><% =Temp %></td>
							<td><% =rsSensores("TVa_Unidades") %></td>
							<td><% =rsSensores("Sen_AlarmaBaja") %></td>
							<td><% =rsSensores("Sen_AlarmaAlta") %></td>
						</tr>

						<%
						rsSensores.MoveNext
					Wend
					%>
						
				</table>
			</td>
		</tr>
	</table>


</BODY>
</HTML>